asp ile resmin bir bölümünün gösterilmesi

[leylaz]

Elmalar birbirlerine çok yakın olduğu için birebir ayrı durmuyorlar.
Dosyayı inceleyebilirisin. Dilimlemeyi Photooshop ile yapılabiliyor.

[yyyaaab]

sanırım ben bulamadım ama dosyayı incele derken dosyamı ekledin

[sato38]

Upload formundan gelen resmi crop eden asp kodu istersen formdan gelen resim yerine veri tabanından aldığın resim konumunu verip te o resmi crop edebilirsin.

Resmi upload için form kodu

<form action="image-crop-demo.asp" method="post" enctype="multipart/form-data">
  Upload an image for processing<br>
  <input type="file" name="Image1"><br>
  <input type="submit" value="Upload">
</form>

Formdan gelen resmi crop edecek olan asp kodu "image-crop-demo.asp"

<%@ language="vbscript" %>
<%
option explicit
'----------------------------------------------------------------
' Crop-to-fit ASPJPEG
' Revision 2 [2009-06-01]
' Corrected aspect ratio of the output image
'----------------------------------------------------------------
const DESIRED_IMAGE_WIDTH = 150
const DESIRED_IMAGE_HEIGHT = 150
dim oUpload
set oUpload = Server.CreateObject( "PERSITS.UPLOAD" )
'
' Ideally, you should set the properties for ASPUPLOAD component here
'
oUpload.Save
dim oFile
set oFile = oUpload.Files( "Image1" )
dim oJpeg
set oJpeg = Server.CreateObject( "PERSITS.JPEG" )
'
' Ideally, you should set the properties for PERSITS.JPEG component here
'
'
' This example requires that PreserveAspectRatio is set to FALSE
' Otherwise you may notice round-off errors when ASPJPEG resizes the image
'
oJpeg.PreserveAspectRatio = false
oJpeg.OpenBinary( oFile.Binary )
dim SourceAspectRatio
dim DesiredAspectRatio
SourceAspectRatio = oJpeg.Width / oJpeg.Height
DesiredAspectRatio = DESIRED_IMAGE_WIDTH / DESIRED_IMAGE_HEIGHT
if SourceAspectRatio > DesiredAspectRatio then
'
' Triggered when source image is wider
'
oJpeg.Height = DESIRED_IMAGE_HEIGHT
oJpeg.Width = DESIRED_IMAGE_HEIGHT * SourceAspectRatio
else
'
' Triggered otherwise (i.e. source image is similar or taller)
'
oJpeg.Width = DESIRED_IMAGE_WIDTH
oJpeg.Height = DESIRED_IMAGE_WIDTH / SourceAspectRatio
end if
dim X0
dim Y0
dim X1
dim Y1
'
' Crop the image keeping the CENTER part intact
'
X0 = ( oJpeg.Width - DESIRED_IMAGE_WIDTH ) / 2
Y0 = ( oJpeg.Height - DESIRED_IMAGE_HEIGHT ) / 2
X1 = X0 + DESIRED_IMAGE_WIDTH
Y1 = Y0 + DESIRED_IMAGE_HEIGHT
oJpeg.Crop X0, Y0, X1, Y1
oJpeg.SendBinary
%>

[leylaz]

sanırım ben bulamadım ama dosyayı incele derken dosyamı ekledin

Eklemeyi unutmuşum kusura bakmayın.
http://www.dosyaupload.net/download....%F6r%20(2).rar

Resim dilimli olduğu için pop upta açtırırken istediğiniz parçayı gösterebilirsiniz.

[yyyaaab]

öncelikle ilgin için tşk ederim ama bu yaptığını bende düşündüm de çok zor şöyleki

100 resim olduğunu düşün ve bu yüz resimde 100 elma olduğunu düşün 100X100=10000 resim eder ve bunu yapmak hiç kolay değil

benim istediğim şey resmin üstüne işaret koyacam programda o işareti seçtiğimde resmin sadece o işaretin olduğu kısmı gözükecek